Excel VBAでデータ入力をスマートに！入力値に合わせた選択肢の表示方法

Private Sub Workbook_Open()

'Worksheetオブジェクトを入れる変数を宣言
 Dim Ws1, Ws2 As Worksheet
  
'Worksheetオブジェクトを取得
 Set Ws1 = Worksheets("Sheet1")
 Set Ws2 = Worksheets("Sheet2")
   
'C5セルが空であれば初期値を設定
 If IsEmpty(Ws1.Range("C5").Value) Then
  Ws1.Range("C5").Value = "野菜"
 End If

'Range("C5:C10") のセル範囲に対して、データバリデーションの設定を行います。
'Validation（入力規則）は、セルに適用される条件を定義するものです。
 With Ws1.Range("C5:C10").Validation  '最初に選択するセルの範囲

    '既存のデータバリデーションを削除します。
    'これにより、指定したセル範囲に以前に設定されていたデータバリデーションがクリアされます。
    .Delete

    'データバリデーションを新たに追加します。具体的には、リスト形式のデータバリデーションを設定しています。'
    'Type:=xlValidateList: リスト形式のデータバリデーションを指定します。
    'Formula1:="=Sheet2!$B$3:$D$3": 「Sheet2」に作成したバリデーションの対象範囲のリストを指定します。
    'ここでは、B3からD3までのセル範囲にあるリストを指定しています。
    .Add Type:=xlValidateList, Formula1:="=Sheet2!$B$3:$D$3"  '最初に選択するカテゴリを指定

    '空白セルを無視するように設定します。
    'これにより、データバリデーションが適用されたセルに対して空白のままで保存できるようになります。
    .IgnoreBlank = True

    'セル内にドロップダウンリストを表示するように設定します。
    'これにより、ユーザーがセルをクリックすると、指定されたリストから値を選択できるようになります。
    .InCellDropdown = True

 End With

'シート「Sheet2」を選択
 Ws2.Select

'選択肢一覧表の範囲を指定するためのカウント変数を宣言
 Dim i As Integer
 
'Sheet2の特定の範囲に対して列番号を変数 i を使用してループ
 For i = 2 To 4

    '2行目から下に連続する非空セルの範囲を取得し、Range オブジェクトに設定します。
    '選択肢の表の3行目、i列目のセルの値を名前として付けます。
     Ws2.Range(Cells(4, i), Cells(4, i).End(xlDown)).Name = Ws2.Cells(3, i).Value

 Next

'シート「Sheet1」を選択
 Ws1.Select
  
'シート「Sheet1」のRange("D5:D10") のセル範囲に対して、データバリデーションの設定を行います。
 With Ws1.Range("D5:D10").Validation  '入力値に応じて表示される選択肢のセル範囲
    
    '既存のデータバリデーションを削除します。
    'これにより、指定したセル範囲に以前に設定されていたデータバリデーションがクリアされます。
    .Delete

    '.Add Type:=xlValidateList, Formula1:="=INDIRECT($C5)": データバリデーションを新たに追加します。
    '具体的には、リスト形式のデータバリデーションを設定しています。
    'Type:=xlValidateList: リスト形式のデータバリデーションを指定します。
    'Formula1:="=INDIRECT($C5)": バリデーションの対象範囲のリストを指定します。
    'ここでは、$C5 のセルに記載されているセル参照を使ってリストを指定しています。
    'INDIRECT 関数は、セル参照を使ってセルの内容を取得します。
    .Add Type:=xlValidateList, Formula1:="=INDIRECT($C5)"

 End With
  
End Sub