Excelでメールアドレスと電話番号の正当性をチェックする方法

'VBAコード内で未宣言の変数の使用を禁止するOption Explicitステートメント
Option Explicit

'Judgというグローバル変数を文字列型として宣言しています。
'この変数は、電話番号が固定電話か携帯電話かを示すために使用されます。
Public Judg As String

'JudgStartサブルーチンの開始
Sub JudgStart()

    'Shというワークシートオブジェクトを宣言し、ThisWorkbookから"Sheet1"を取得します。
    Dim Sh As Worksheet
    Set Sh = ThisWorkbook.Sheets("Sheet1")

    'ワークシート上の範囲"D5:D14"および"F5:F14"の既存データをクリアします。
    Sh.Range("D5:D14").ClearContents
    Sh.Range("F5:F14").ClearContents

    'Tarという範囲オブジェクトを宣言し、"C5:E14"の範囲を指定します。
    'これがJudgStartサブルーチンの対象範囲です。
    Dim Tar As Range
    Set Tar = Sh.Range("C5:E14")

    'Tar内の各セルに対して繰り返し処理を行います。
    Dim Cell As Range
    For Each Cell In Tar

        'セルが3列目（C列）であるかを判定します。メールアドレスの列であることを示します。
        If Cell.Column = 3 Then

            'MailJudg関数でメールアドレスの正当性を検証し、
            '誤っていれば対応するメールアドレスの右側のセルに"×"を記入します。
            If Not MailJudg(Cell.Value) Then
                Cell.Offset(0, 1).Value = "×" 
            End If

        'セルが5列目（E列）であるかを判定します。電話番号の列であることを示します。
        ElseIf Cell.Column = 5 Then

            'TelJudg関数で電話番号の正当性を検証し、
            '誤っていれば対応する電話番号の右側のセルに"×"を記入し、
            '正しい場合はJudgの値をセルに記入します。
            If Not TelJudg(Cell.Value) Then
                Cell.Offset(0, 1).Value = "×"
            Else
                Cell.Offset(0, 1).Value = Judg
            End If

        End If

    '対象範囲内のすべてのセルに対する処理が終了し、次の行に進みます。
    Next Cell

    'メッセージボックスを表示して、メールアドレスと電話番号の検証が完了したことを
    'ユーザーに知らせます。
    MsgBox "メールアドレスと電話番号の検証が完了しました。", vbInformation

'JudgStartサブルーチンの終了。
End Sub


'MailJudg関数の開始。メールアドレスの正当性を判定する関数です。
Function MailJudg(ByVal MailAd As String) As Boolean

    '正規表現オブジェクトを作成します。これにより、メールアドレスのパターンを検証します。
    Dim Reg As Object
    Set Reg = CreateObject("VBScript.RegExp")

    '正規表現のグローバルフラグをTrueに設定します。
    'Global プロパティが True の場合、正規表現は対象文字列全体を検索し、
    'マッチする全ての箇所を返します。
    Reg.Global = True

    '正規表現パターンを指定し、メールアドレスの形式を検証するためのパターンを設定します。
    Reg.Pattern = "^[a-zA-Z0-9._%+-]+@[a-zA-Z0-9.-]+\.[a-zA-Z]{2,}$"

    '指定されたメールアドレスが正しい形式であるかどうかをTestメソッドで判定し、
    'その結果を返します。
    MailJudg = Reg.Test(MailAd)

'MailJudg関数の終了。    
End Function


'TelJudg関数の開始。電話番号の正当性を判定する関数です。
Function TelJudg(ByVal TelNumber As String) As Boolean

    '正規表現オブジェクトを作成します。これにより、電話番号のパターンを検証します。
    Dim Reg As Object
    Set Reg = CreateObject("VBScript.RegExp")

    '正規表現のグローバルフラグをTrueに設定します。
    'Global プロパティが True の場合、正規表現は対象文字列全体を検索し、
    'マッチする全ての箇所を返します。
    Reg.Global = True
        
    '正規表現パターンを指定し、電話番号が固定電話の形式であるかどうかを検証し、
    'その結果をTelJudgに格納します。
    Reg.Pattern = "^0(?!70|80|90)\d{1,4}-\d{1,4}-\d{4}$"
    TelJudg = Reg.Test(TelNumber)

    '固定電話である場合はJudgに"固定"を格納します。
    If TelJudg = True Then
     Judg = "固定"

    '以下、固定電話でなかった場合の処理 
    Else

     '新しい正規表現パターンを指定し、電話番号が携帯電話の形式であるかどうかを検証し、
     'その結果をTelJudgに格納します。
     Reg.Pattern = "^0[789]0-[0-9]{4}-[0-9]{4}$"
     TelJudg = Reg.Test(TelNumber)

     '携帯電話である場合はJudgに"携帯"を格納します。
     '携帯電話の形式でもない場合は、Judgに値が格納されません。
     If TelJudg = True Then
      Judg = "携帯"
     End If

    'TelJudg関数の終了    
    End If
       
End Function