VBAでグラフを自動作成！サンプルアプリのご紹介

'VBAコードで変数を宣言する際、未宣言の変数を許可しないオプションを設定。
'これにより、タイプミスや変数の未宣言を防ぎ、コードの品質を向上させます。
Option Explicit

'これより3Dグラフの作成を開始
Sub グラフを作成()
  
 '変数myRangeを宣言し、その型をRangeに設定
  Dim myRange As Range
 
 '変数myRangeにワークシート上の"B17:G30"のセル範囲をセット
 '以下で3Dグラフのデータ範囲として使用
  Set myRange = Range("B17:G30")
  
'ChartObjects.Addメソッドを使用して、指定された位置とサイズで新しい3Dグラフを作成。
'With文を使ってこれに対する処理をまとめています。
  With ActiveSheet.ChartObjects.Add( _
      myRange.Left, myRange.Top, myRange.Width, myRange.Height)
      
      '作成した3Dグラフに名前を付与
      .Name = "成績(3Dグラフ)"
      
      '3Dグラフのデータソースを"C4:F14"に設定
      .Chart.SetSourceData Range("C4:F14")
      
      'グラフの種類を3D柱グラフに設定
      .Chart.ChartType = xl3DColumn
      
      'グラフを回転させる角度を15度に設定
      .Chart.Rotation = 15
      
      'グラフの奥行きを40度に設定
      .Chart.Elevation = 40
   
  'Withブロックの終了
   End With
   
  '作成した3Dグラフに対する追加の処理を行うため、再びWith文を使用
   With ActiveSheet.ChartObjects("成績(3Dグラフ)").Chart

      '3Dグラフにタイトルを追加し、そのフォントサイズを設定
      .HasTitle = True
      .ChartTitle.Text = "成績3Dグラフ"
      .ChartTitle.Font.Size = 16

  'Withブロックの終了
   End With


  '以下同様の手順で2Dグラフを作成
  '変数myRangeにワークシート上の"B17:G30"のセル範囲をセット
   Set myRange = Range("i4:N14")
     
  'ChartObjects.Addメソッドを使用して、指定された位置とサイズで新しい2Dグラフを作成。
  'With文を使ってこれに対する処理をまとめています。
   With ActiveSheet.Shapes.AddChart2 _
        (Style:=-1, XlChartType:=xlColumnStacked, Left:=myRange.Left, _
         Top:=myRange.Top, Width:=myRange.Width, Height:=myRange.Height)

     '作成した2Dグラフに名前を付与
     .Name = "成績(2Dグラフ)"
     
     '2Dグラフのデータソースを"C4:F14"に設定
     .Chart.SetSourceData Range("C4:F14")

  'Withブロックの終了
   End With
   
  '2Dグラフにタイトルを追加し、そのフォントサイズを設定
   With ActiveSheet.ChartObjects("成績(2Dグラフ)").Chart
      .HasTitle = True
      .ChartTitle.Text = "成績2Dグラフ"
      .ChartTitle.Font.Size = 16
   End With
   
  '2Dグラフに凡例を追加
   With ActiveSheet.ChartObjects("成績(2Dグラフ)").Chart
      .HasLegend = True
      .Legend.Position = xlLegendPositionRight
   End With
   
End Sub

'グラフを削除するためのサブルーチン
Sub グラフを削除()

 'wsとgrという2つの変数を宣言
 'wsはワークシートを、grはグラフオブジェクトを指定
  Dim ws As Worksheet
  Dim gr As ChartObject
  
 '変数wsにワークシート"Sheet1"をセット
  Set ws = Worksheets("Sheet1")
  
 'wsワークシート上のすべてのグラフオブジェクトに対してループを実行
  For Each gr In ws.ChartObjects
  
   'グラフの名前が「成績(3Dグラフ)」または「成績(2Dグラフ)」の場合にグラフ削除処理を実行
    If gr.Name = "成績(3Dグラフ)" Or gr.Name = "成績(2Dグラフ)" Then
    
     'グラフを削除
      gr.Delete

    'If文終了
    End If
  
 '次のグラフに進みます。
  Next gr

'サブルーチン終了
End Sub